load (draw);

koordx : 4;
koordy : 4;

A : [3, 2, 3];
U : [0, 0];
e1 : [-1,-1];
e2 : [1,0];
e3 : [0,1];

anzahlbilder : 0;

koord : [
  line_width = 2,
  head_length = 0.2,
  xrange = [-koordx, koordx],
  yrange = [-koordy, koordy],
  color = black,
  xtics = [-koordx+1, 1, koordx-1],
  ytics = [-koordy+1, 1, koordy-1],
  vector ([-koordx, 0], [2*koordx, 0]),    /* x-Achse */
  vector ([0, -koordy], [0, 2*koordy]),   /* y-Achse */
  vector ([0, 0], [-3.5, -3.5]),   /* z-Achse */
  xaxis = true, xtics_axis  = true,
  yaxis = true, ytics_axis  = true,
  point_type = none,
  points_joined = true,
  points ([-1.05,-0.95],[-0.95,-1.05]),
  points ([-2.05,-1.95],[-1.95,-2.05]),
  points ([-3.05,-2.95],[-2.95,-3.05]),
  label (["1", -0.8, -1.1]),
  label (["2", -1.8, -2.1]),
  label (["3", -2.8, -3.1]),
  points_joined = false
];

settings: [
       line_width = 3
    ];

for i : 0 while i <= A[1] do
  block ([],
    T : i * e1,
    bild[anzahlbilder] : 
      gr2d (
        koord, settings,
        color = red,
        vector(U,T)
      ),
    anzahlbilder : anzahlbilder + 1
  );

for i : 0 while i <= A[2] do
  block ([],
    T : i * e2,
    bild[anzahlbilder] :
      gr2d (
        koord, settings,
        color = red,
        vector(U,A[1]*e1),
        color = green,
        vector(A[1]*e1, T)
      ),
    anzahlbilder : anzahlbilder + 1
  );

for i : 0 while i <= A[3] do
  block ([],
    T : i * e3,
    bild[anzahlbilder] :
      gr2d (
        koord, settings,
        color = red,
        vector(U,A[1]*e1),
        color = green,
        vector(A[1]*e1, A[2]*e2),
        color = blue,
        vector(A[1]*e1 + A[2]*e2, T)
      ),
    anzahlbilder : anzahlbilder + 1
  );

  for i : 0 while i <= 2 do
  block ([],
    bild[anzahlbilder] :
      gr2d (
        koord, settings,
        color = red,
        vector(U,A[1]*e1),
        color = green,
        vector(A[1]*e1, A[2]*e2),
        color = blue,
        vector(A[1]*e1 + A[2]*e2, A[3]*e3),
        line_width = 5,
        point_size = 6,
        point_type = multiply,
        points ([A[1]*e1 + A[2]*e2 + A[3]*e3])
      ),
    anzahlbilder : anzahlbilder + 1
  );

bilder : [bild[0]];
for i : 1 while i < anzahlbilder do
    bilder : append (bilder, [bild[i]])$

draw (
  bilder,
  delay = 100,

  file_name = "koord3deintragen_animation2",
  dimensions = [600,600],
  terminal = animated_gif
);